PN V24A3Q
;*************************************
;
;Teiber fuer V24-Drucker (V24A3, Quelle)
;
;Stand: 19.6.86
;
;*************************************
;
;Treiberaufbau entsprechend Beschreibung
;"Betriebssystem Z9001"
;Abschnitt "3. Zusaetzliche Treiber"
;
;************************************
;
;Geeignet fuer alle Drucker mit Schnittstelle
;RS232C und DTR-Protokoll (Hardware-Protokoll)
;
;
;Verwendbar sind alle Drucker- und Schreib-
;maschinen-Module mit abgeschaltetem EPROM
;und an den Drucker angepassten Steckverbinder
;
;************************************
;
;Anschluss Drucker an Modulkabel
;
;Modulkabel           Drucker
;
;Schirm:SG -----------SG
;blau  :TxD>--------->RxD
;rot   :CTS<---------<DTR
;                     (bei S6010: RTS)
;
; ------------------------------------------
;                            Leitungsbe-
;      Name                  zeichnung nach
;                            CCITT  EIA DIN
; ------------------------------------------
; SG   Betriebsmasse         102    AB  E2
; TxD  Sendedaten            103    BA  D1
; RxD  Empfangsdaten         104    BB  D2
; RTS  Sendeteil einschalten 105    CA  S2
; CTS  Sendebereitschaft     106    CB  M2
; DTR  Betriebsbereitschaft  108.2  CD  S1.2
; ------------------------------------------
;
;************************************
;
;Parameter zur Anpassung des Treibers
;an verschiedene Einsatzbedinungen
;
;====================================
;
;Programmanfang: ANF (auf 100H-Grenze!)
;
;------------------------------------
;
;Baudrate: BDRAT in Bd
;    BDRAT=50, 75, 100, 150, 200, 300, 600,
;          1200, 2400, 4800 oder 9600
;
;Zeitkonstante fuer CTC: ZKCTC=9600/BDRAT
;
;------------------------------------
;
; Datenbit: DABI
;    7 Datenbit: DABI=20H
;    8 Datenbit: DABI=60H
;
;------------------------------------
;
; Paritaetsbit: PABI
;    ohne     Paritaet: PABI=2
;    gerade   Paritaet: PABI=3
;    ungerade Paritaet: PABI=1
;
;------------------------------------
;
; Stopbit: STPBI
;    1   Stopbit: STPBI=4
;    1.5 Stopbit: STPBI=8
;    2   Stopbit: STPBI=0CH
;
;------------------------------------
;
; Portadressen
;    Adresse SIO-Kanal Daten    : SIODA
;         - " -        Kommandos: SIOKD
;    Adresse CTC-Kanal          : CTC
;
;************************************
;
;Vereinbarungen
;
;====================================
;
ANF:EQU 0BF00H;Programmanfang
;------------------------------------
;
ZKCTC:EQU 1;9600 Bd
DABI:EQU 60H;8 Datenbit
PABI:EQU 2;ohne Paritaet
STPBI:EQU 4;1 Stopbit
;------------------------------------
SIODA:EQU 0B0H;Datenadr SIO Kanal A
SIOKD:EQU SIODA+2;Kdoadr   - " -
CTC:EQU 0A8H;Adr CTC Kanal 0
;------------------------------------
IOBYT:EQU 4
ASV:EQU 0FH
LISW:EQU 15H
PU:EQU 2FH
DRADR:EQU 0EFE1H;Adr.Druckertreiber
DRNAM:EQU 0EFEFH;Name Druckertreiber
CSTS:EQU 0F006H;Consol-Status
CONSI:EQU 0F009H;Consol-Input
;------------------------------------
STOP:EQU 3;STOP-Taste
LF:EQU 0AH;Line feed
CR:EQU 0DH;Cariage	return
COP:EQU 10H;CONTR-P
;
;************************************
;
ORG ANF
;
;************************************
;
;Treiberinitialisierung
;
;====================================
;
KOPF3:JMP DINI3;Ohne Steuerzeichen-
NAME3:DB 'V24A3   '; auswertung
DA 0	;Alle Zeichen unveraendert
;
;====================================
;
DINI3: CALL DIA3
JRC DINIF-#;Fehler
;      ------------------------------
LD HL,NAME3
LD BC,OL3
;      ------------------------------
DINIE:LD (DRNAM),HL
LD (DRADR),BC
LD A,(IOBYT)
AND 3FH
LD (IOBYT),A
;      ------------------------------
AND A	;CY=0
RET
;------------------------------------
DINIF:LD A,0;Korr. Monitor
LD (LISW),A; Version 1.1.
;      ------------------------------
LD A,4;Fehler-Nr.
RET
;
;====================================
DIA3:LD DE,TPAPO;Text
LD C,9
CALL 5; anzeigen
LD HL,PROGT
LD B,3
LD C,CTC
OTIR
LD B,9
LD C,SIOKD
OTIR
AND A;CY=0
RET
;====================================
TPAPO:DB LF
DB 'Papier positionieren!'
DB CR
DB LF
DB 0
;====================================
;
PROGT:DB 3;CTC
DB 17H
DB ZKCTC
DB 18H;SIO
DB 4
DB 40H+PABI+STPBI
DB 1
DB 0
DB 3
DB 0C0H
DB 5
DB DABI+8
;
;************************************
;
;Ausgaberoutine fuer Drucker

;====================================
;
OL3:INC A
JPZ DIA3;A=FF
;      ------------------------------
OLE:DEC A
JPZ STA;A=0
;      ------------------------------
DEC A
DEC A
JRNZ OLF-#
CALL DOUT	;A=2
RNC
;      ------------------------------
OLF:XOR A	;Korr.Monitor
LD (LISW),A	; Version 1.1.
;      ------------------------------
SCF	;Fehler
RET	; Treiberaufruf
;************************************
;
;Datenausgabe
;
;====================================
;
DOUT:NOP;Zeichen in C
;------------------------------------
;
;Hier kann vom Anwender bei Bedarf eine
;Sonderbehandlung fuer bestimmte Zeichen
;eingefuegt werden.
;      ------------------------------
;Beispiel 1: Grafikzeichen unterdruecken
;
;      LD   A,7FH
;      CMP   C                  ;C>7FH?
;      CCY
;      RNC                     ;Ja-->RET
;      JR   DOUT2-#
;      ------------------------------
;Beispiel 2: Klein- in Grossbuchstaben wandeln
;
;      LD   A,C
;      SUB  61H                ;61H<=C<=7AH?
;      CMP  1BH
;      JRC  DOUT2-#            ;Nein-->DOUT2
;      RES  5,C
;      JR   DOUT2-#
;      ------------------------------
;Beispiel 3: Null mit Schraegstrich
;
;      LD   A,'0'
;      CMP  C                  ;C=30H?
;      JRNZ DOUT2-#            ;Nein-->DOUT2
;      CALL DOUT2              ;Null
;      RC
;      LD   C,8
;      CALL DOUT2              ;Rueckschritt
;      RC
;      LD   C,'/'
;      JR   DOUT2-#            ;Schraegstrich
;------------------------------------
DOUT2:PUSH BC
PUSH DE
PUSH HL
LD HL,(PU)
LD A,(ASV)
LD H,A
PUSH HL
;      ------------------------------
CALL CSTS
JRC DOUT8-#	;CY=1
AND A
JRZ DOUT8-#;CY=0
CMP STOP
SCF
JRZ DOUT8-#;CY=1
XOR COP
JRNZ DOUT8-#;CY=0
XOR A
LD (LISW),A
CALL CONSI
;      ------------------------------
DOUT8:POP HL
LD A,H
LD (ASV),A
LD A,L
LD (PU),A
POP HL
POP DE
POP BC
RC	;Fehler-->RET
;      ------------------------------
CALL STA
AND A
JRZ DOUT2-#
;      ------------------------------
LD A,C
OUT SIODA;Zeichen-->SIO
RET 
;
;
;************************************
;
;Statusabfrage
;
;====================================
;
STA:LD A,10H
OUT SIOKD
IN SIOKD	;SIO RR0
AND 24H
CMP 24H
RZ;Bereit (A<>0)
;------------------------------------
XOR A	;Nicht bereit
RET	; (A=0)
;
;************************************
END:EQU #-1
LAENG:EQU #-ANF
END